Μερικές Διαφορικές Εξισώσεις

Εξίσωση Laplace ($\nabla^2 u=0$)

Πολικές συντεταγμένες

Clear["Global`*"]
PDE = Laplacian[u[φ, ρ], {ρ, φ}, "Polar"] // Expand
\[\frac{u^{(0,1)}(\varphi ,\rho )}{\rho }+u^{(0,2)}(\varphi ,\rho )+\frac{u^{(2,0)}(\varphi ,\rho )}{{\rho }^{2}}\]
r = 5;
f[φ_] := Cos[φ] + (Sin[φ])^2 + (Cos[φ])^3
u[φ_, ρ_] := R[ρ]*Φ[φ]
(ρ^2 PDE[[1]])/( R[ρ]*Φ[φ]) // Expand
\[\frac{\rho (R')[\rho ]}{R[\rho ]}\]
eqR = ρ Derivative[1][R][ρ] + ρ^2 R''[ρ] == λ*R[ρ]
eqΦ = Φ''[φ] == -λ*Φ[φ]
\[\rho (R')[\rho ]+({\rho }^{2}) (R'')[\rho ]=\lambda R[\rho ]\]
\[(\Phi '')[\varphi ]=-\lambda \Phi [\varphi ]\]

Πάμε να λύσουμε τη δεύτερη Σ.Δ.Ε. για τα διάφορα πιθανά λ.

Assuming[λ < 0, DSolve[eqΦ, Φ, φ]]
Assuming[λ == 0, DSolve[eqΦ, Φ, φ]]
Assuming[λ > 0, DSolve[eqΦ, Φ, φ]]
\[{{\Phi \to Function[{\varphi },C_{1} \cosh((\sqrt{-\lambda }) \varphi )+I C_{2} \sinh((\sqrt{-\lambda }) \varphi )]}}\]
\[{{\Phi \to Function[{\varphi },C_{1}]}}\]
\[{{\Phi \to Function[{\varphi },C_{1} \cos((\sqrt{\lambda }) \varphi )+C_{2} \sin((\sqrt{\lambda }) \varphi )]}}\]

Η μόνη περίπτωση που σέβεται την περιοδικότητα της συνάρτησης Φ και τον μη-μηδενικό χαρακτήρα της είναι η τελευταία. Οπότε θα θέσουμε λ==n^2 και θα λύσουμε την άλλη Σ.Δ.Ε., για να βρούμε το R.

λ = n^2;
eqΦ
DSolve[eqΦ, Φ[φ], φ]
eqR
DSolve[eqR, R[ρ], ρ]
\[(\Phi '')[\varphi ]=-(n^{2}) \Phi [\varphi ]\]
\[{{\Phi [\varphi ]\to C_{1} \cos(n \varphi )+C_{2} \sin(n \varphi )}}\]
\[\rho (R')[\rho ]+({\rho }^{2}) (R'')[\rho ]=(n^{2}) R[\rho ]\]
\[{{R[\rho ]\to C_{1} \cosh(n \ln(\rho ))+I C_{2} \sinh(n \ln(\rho ))}}\]

Έχουμε, συνεπώς, για τη συνάρτηση Φ:

Clear[Φ]
Φ[φ_, n_] := a[n]*Cos[n φ] + b[n]*Sin[n φ]

Όσον αφορά τη συνάρτηση R, προφανώς:

$\cosh(n\ln(\rho))=\frac{e^{n\ln(\rho)}+e^{-n\ln(\rho)}}{2}=\frac{\rho^n+\rho^{-n}}{2}$ και $\sinh(n\ln(\rho))=\frac{e^{n\ln(\rho)}-e^{-n\ln(\rho)}}{2}=\frac{\rho^n-\rho^{-n}}{2}$.

Επομένως κάποιοι από τους γραμμικούς συνδυασμούς θα είναι συναρτήσεις της μορφής $ρ^n$. Πάμε να το ελέγξουμε και μέσω του Mathematica:

C[1] Cosh[n Log[ρ]] + I C[2] Sinh[n Log[ρ]] // TrigToExp
Clear[R]
R[ρ_, s_] := ρ^s
\[(\frac{1}{2}) ({\rho }^{-n}) C_{1}+(\frac{1}{2}) ({\rho }^{n}) C_{1}-(\frac{1}{2}) I ({\rho }^{-n}) C_{2}+(\frac{1}{2}) I ({\rho }^{n}) C_{2}\]

Καθόσον οι όροι ρ^-n οδηγούν σε ανεπιθύμητους απειρισμούς, έχουμε την αναμενόμενη απάντηση στις εξισώσεις Euler R(ρ)==ρ^n.
Προσπαθούμε ακολούθως να εκφράσουμε τη γενική λύση σε μορφή σειράς. 

uSeries[φ_, ρ_, n_] := Sum[R[ρ, j]*Φ[φ, j], {j, 0, n}]
uSeries[φ, ρ, 4]
\[a(0)+\rho (a(1) \cos(\varphi )+b(1) \sin(\varphi ))+({\rho }^{2}) (a(2) \cos(2 \varphi )+b(2) \sin(2 \varphi ))+({\rho }^{3}) (a(3) \cos(3 \varphi )+b(3) \sin(3 \varphi ))+({\rho }^{4}) (a(4) \cos(4 \varphi )+b(4) \sin(4 \varphi ))\]

Το όλο ζήτημα τώρα είναι να βρούμε τους συντελεστές a[n] και b[n], ώστε να ισχύει:

$a_0+r(a_ 1\cos(\phi)+b_ 1\sin(\phi))+r^2(a_ 2\cos(2\phi)+b_2\sin(2\phi))+r^3(a_ 3\cos(3\phi)+b_ 3\sin(3\phi))+\cdots=f(\phi).$

Οπότε θα πάρουμε το εσωτερικό γινόμενο με τις συναρτήσεις cos(nφ) και sin(nφ).

a[0] = Integrate[f[φ], {φ, 0, 2 Pi}]/Integrate[1, {φ, 0, 2 Pi}]
b[0] = 0;
a[n_] := Integrate[f[φ]*Cos[n*φ], {φ, 0, 2 Pi}]/
 Integrate[r^n (Cos[n*φ])^2, {φ, 0, 2 Pi}]
b[n_] := Integrate[f[φ]*Sin[n*φ], {φ, 0, 2 Pi}]/
 Integrate[r^n (Sin[n*φ])^2, {φ, 0, 2 Pi}]
\[\frac{1}{2}\]

Ας δούμε τους πρώτους 11 συντελεστές.

TableForm[Table[{n, a[n], b[n]}, {n, 0, 10}], 
 TableHeadings -> {None, {"n", "a[n]","b[n]"}}]
\[\begin{pmatrix} "n" & "a(n)" & "b(n)" \\ 0 & \frac{1}{2} & 0 \\ 1 & \frac{7}{20} & 0 \\ 2 & -\frac{1}{50} & 0 \\ 3 & \frac{1}{500} & 0 \\ 4 & 0 & 0 \\ 5 & 0 & 0 \\ 6 & 0 & 0 \\ 7 & 0 & 0 \\ 8 & 0 & 0 \\ 9 & 0 & 0 \\ 10 & 0 & 0 \end{pmatrix}\]

Παρατηρούμε πως αυτοί μηδενίζονται για n>3. Μήπως όμως αυτό συμβαίνει μόνο για τα n που δοκιμάσαμε; Θα προσπαθήσουμε να αναλύσουμε την f σε όρους της μορφής sin(nφ) και cos(nφ).

TrigReduce[f[φ]]
\[(\frac{1}{4}) (2+7 \cos(\varphi )-2 \cos(2 \varphi )+\cos(3 \varphi ))\]

Παρατηρούμε ότι η f αφενός αποτελείται μόνο από συνημίτονα, αφετέρου αυτά φτάνουν μέχρι το cos(3φ). Λόγω ορθογωνιότητας, λοιπόν, τα εσωτερικά γινόμενα της f με τα cos(nφ) για n>3 και όλα τα sin(nφ) θα είναι 0, όπερ συμπαρασύρει και τα αντίστοιχα $a_n, b_n$.
Έτσι, η λύση μας αποτελείται μόνο από 4 (=3+1) όρους.

Clear[u]
u[φ_, ρ_] := Evaluate[uSeries[φ, ρ, 3]]
u[φ, ρ]
ParametricPlot3D[{ρ Cos[φ], ρ Sin[φ], u[φ, ρ]}, {ρ, 0, r}, {φ, 0,  2 Pi}]
\[\frac{1}{2}+(\frac{7}{20}) \rho \cos(\varphi )-(\frac{1}{50}) ({\rho }^{2}) \cos(2 \varphi )+(\frac{1}{500}) ({\rho }^{3}) \cos(3 \varphi )\]
3D Plot